REM This file controls the orderly and unobtrusive startup and shutdown of HAMLIB and Gpredict on Windows
REM Created by The School Amateur Radio Club Network: www.sarcnet.org

REM Installation:

REM Step 1. Create a new Tracking folder in your Documents folder 

REM Step 2. Copy this text file to the new Tracking folder 

REM Step 3. Install the latest releases of HAMLIB and Gpredict using the following links:
REM HAMLIB: https://github.com/Hamlib/Hamlib/wiki/Download#latest-release
REM Gpredict: https://github.com/csete/gpredict/releases

REM Step 4. Change the following program paths (typically just the numbers) to suit your installation:
set ROTCTLD=C:\"Program Files"\hamlib-w64-4.5.5\bin\rotctld.exe
set RIGCTLD=C:\"Program Files"\hamlib-w64-4.5.5\bin\rigctld.exe
set GPREDICT=C:\"Program Files"\gpredict-win32-2.3.37\gpredict.exe

REM Step 5. Plug your rotator and rig into separate USB ports on your PC and power everything up
 
REM Step 6. Change the following rotator control settings to suit your installation:
REM For supported rotator types see: https://github.com/Hamlib/Hamlib/wiki/Supported-Rotators. Note: Use 202 for our SARCNET rotators
REM To identify the rotator COM port see: Windows Device Manager
REM See: Your rotator controller manual for the rotator serial port baud rate. Note: Use 9600 for our SARCNET rotators
set ROTTYPE=202
set ROTPORT=COM6
set ROTRATE=9600

REM Step 7. Change the following rig control settings to suit your installation:
REM For supported rig types see: https://github.com/Hamlib/Hamlib/wiki/Supported-Radios 
REM To identify the rig COM port see: Windows Device Manager
REM See: Your rig's configuration menu for the CAT/CIV USB serial port baud rates  
set RIGTYPE=3081
set RIGPORT=COM8
set RIGRATE=38400

REM Step 8. Select File | Save, to save this text file, then select File | Save as, and enter tracking.bat 

REM Step 9. Right-click on the tracking.bat file and select Create shortcut

REM Step 10. Rename the shortcut to Tracking

REM Step 11. Right-click on the Tracking shortcut, select Properties and the Shortcut tab. Select Run Minimised.

REM Step 12. Copy the Tracking shortcut to your Desktop, Start Menu, or Task Bar as you like

REM Step 13. To start HAMLIB and start Gpredict: Double click on the Tracking shortut

REM Step 14. To stop Gpredict and close HAMLIB: Just close Gpredict 

REM Do not change any of the following:

REM Start HAMLIB rotator control and rig control tasks in minimised terminal windows with appropriate titles
start /min "Rotator Control" %ROTCTLD% -m %ROTTYPE% -r %ROTPORT% -s %ROTRATE%  -T 127.0.0.1 -t 4533 -vvvvvv
start /min "Rig Control" %RIGCTLD% -m %RIGTYPE% -r %RIGPORT% -s %RIGRATE% -T 127.0.0.1 -t 4532 -vvvvvv

REM Start Gpredict then wait here until it is closed by the user
start /wait %GPREDICT%

REM Stop HAMLIB rig control 
taskkill /f /im rigctld.exe

REM Stop HAMLIB rotator control 
taskkill /f /im rotctld.exe